Justeringer i import

Justeringer i importen foretages generelt med justeringsleddene til den konkurrerende del af importen, fMz<j>. Relationerne for den konkurrerende import er fejlkorrektionsrelationer. Alle justeringsleddene er justeringsled til vækstraten.

Ønsker man f.eks. at hæve importkvoten i 1. år med ca. 1 pct., sættes J-leddene på følgende måde, i de respektive varegrupper:

  READ lang19 ;
  TIME 2019 2019;
  SERIES jrfmz01 = @jrfmz01 + 0.01 ;
  SERIES jrfmz2  = @jrfmz2  + 0.01 ;
  SERIES jrfmz3q = @jrfmz3q + 0.01 ;
  SERIES jrfmz59 = @jrfmz59 + 0.01 ;
  SERIES jrfmzs =  @jrfmzs  + 0.01 ;
  SIM <2019 2031> ;

De standardiserede importkvoter kfmz<i> ændres med ca. 1 pct. i 1. år. Når importkvoten på denne måde hæves, vil modellen sørge for, at den danske produktion sænkes tilsvarende.

Resultatet bliver imidlertid kun en stigning på 0,56 pct. på den samlede import. Det skyldes, at JRfMz'erne ikke dækker al import og at en importstigning betyder lavere indenlandsk aktivitet og dermed mindre afledt import. Den indlagte merimport vil forsvinde igen pga. fejlkorrektion.

Et permanent løft i en af de fejlkorrektionsbestemte importkomponenter, f.eks. importen af industrivarer, fM59, kræver at J-leddet JRfMz59 hæves i alle fremtidige perioder. Dynamikken kan være kompliceret, jf. eksemplerne med eksporten.

Nedenstående eksempel viser hvordan der ændres i J-leddet for de forskellige varegrupper indenfor import. Først et eksempel som hæver importen af tjenester umiddelbart med ca 1 pct.:

  READ lang19 ;
  TIME 2019 2019;
  LIST LaMs_1 = aMs_Cb, aMs_Ce, aMs_Cf, aMs_Cg, aMs_Ch, aMs_Co, aMs_Cs;
  LIST LaMs_2 = aMs_Cv, aMs_E01, aMs_E2, aMs_E3x, aMs_E59, aMs_E7y, aMs_Esq;
  LIST LaMs_3 = aMs_Ib, aMs_Ikn, aMs_Imxo7y, aMs_It, aMs_vma, aMs_vmb, aMs_vme;
  LIST LaMs_4 = aMs_vmh, aMs_vmne, aMs_vmnf, aMs_vmng, aMs_vmnz, aMs_vmo, aMs_vmqf;
  for i=#LaMs_1 j=#LaMs_2 k=#LaMs_3 l=#LaMs_4;
  SERIES JD{i} = @JD{i} + @{i}*0.01;
  SERIES JD{j} = @JD{j} + @{j}*0.01;
  SERIES JD{k} = @JD{k} + @{k}*0.01;
  SERIES JD{l} = @JD{l} + @{l}*0.01;
  END;
  SERIES JMs_il     = @JMs_il     + 0.01*@Ms_il;
  SERIES JDaMs_vmqs   = @JDaMs_vmqs + 0.01*@aMs_vmqs;
  SERIES JDaMs_vmqz   = @JDaMs_vmqz + 0.01*@aMs_vmqz;
  SIM <2019 2031> ;

Dernæst tilsvarende for import af person- og lastebiler,

  READ lang19 ;
  TIME 2019 2019;
  LIST LaM7b_1 = aM7b_Cb, aM7b_Ce, aM7b_Cf, aM7b_Cg, aM7b_Ch, aM7b_Co, aM7b_Cs;
  LIST LaM7b_2 = aM7b_Cv, aM7b_E01, aM7b_E2, aM7b_E3x, aM7b_E59, aM7b_E7y, aM7b_Esq;
  LIST LaM7b_3 = aM7b_Ib, aM7b_Ikn, aM7b_Imxo7y, aM7b_It, aM7b_vma, aM7b_vmb, aM7b_vme;
  LIST LaM7b_4 = aM7b_vmh, aM7b_vmne, aM7b_vmnf, aM7b_vmng, aM7b_vmnz, aM7b_vmo,aM7b_vmqf;
  for i=#LaM7b_1 j=#laM7b_2 k=#laM7b_3, l=#LaM7b_4;
  SERIES JD{i} = @JD{i} + @{i}*0.01;
  SERIES JD{j} = @JD{j} + @{j}*0.01;
  SERIES JD{k} = @JD{k} + @{k}*0.01;
  SERIES JD{l} = @JD{l} + @{l}*0.01;
  END;
  SERIES JM7b_il       = @JM7b_il + 0.01*@M7b_il ;
  SERIES JDaM7b_vmqs   = @JDaM7b_vmqs + 0.01*@aM7b_vmqs;
  SERIES JDaM7b_vmqz   = @JDaM7b_vmqz + 0.01*@aM7b_vmqz;
  SIM <2019 2031> ;

Importen kan også påvirkes indirekte. Det kan f.eks. ske ved at påvirke dele af efterspørgslen med stor importindhold. I eksemplet nedenfor øges bilforbruget. Bilkøb og klargøring af biler har et stort importindhold.

  READ lang19 ;
  TIME 2019 2031 ;
  SERIES jrbfcbu = @jrbfcbu   + (((0.01*fM7b*pm7b/pcbu)/fCpuetxh)/bfcbu) ;
  SIM <2019 2031> ;